msousa@353: # ltsugar.m4 -- libtool m4 base layer.                         -*-Autoconf-*-
msousa@353: #
msousa@353: # Copyright (C) 2004, 2005, 2007, 2008 Free Software Foundation, Inc.
msousa@353: # Written by Gary V. Vaughan, 2004
msousa@353: #
msousa@353: # This file is free software; the Free Software Foundation gives
msousa@353: # unlimited permission to copy and/or distribute it, with or without
msousa@353: # modifications, as long as this notice is preserved.
msousa@353: 
msousa@353: # serial 6 ltsugar.m4
msousa@353: 
msousa@353: # This is to help aclocal find these macros, as it can't see m4_define.
msousa@353: AC_DEFUN([LTSUGAR_VERSION], [m4_if([0.1])])
msousa@353: 
msousa@353: 
msousa@353: # lt_join(SEP, ARG1, [ARG2...])
msousa@353: # -----------------------------
msousa@353: # Produce ARG1SEPARG2...SEPARGn, omitting [] arguments and their
msousa@353: # associated separator.
msousa@353: # Needed until we can rely on m4_join from Autoconf 2.62, since all earlier
msousa@353: # versions in m4sugar had bugs.
msousa@353: m4_define([lt_join],
msousa@353: [m4_if([$#], [1], [],
msousa@353:        [$#], [2], [[$2]],
msousa@353:        [m4_if([$2], [], [], [[$2]_])$0([$1], m4_shift(m4_shift($@)))])])
msousa@353: m4_define([_lt_join],
msousa@353: [m4_if([$#$2], [2], [],
msousa@353:        [m4_if([$2], [], [], [[$1$2]])$0([$1], m4_shift(m4_shift($@)))])])
msousa@353: 
msousa@353: 
msousa@353: # lt_car(LIST)
msousa@353: # lt_cdr(LIST)
msousa@353: # ------------
msousa@353: # Manipulate m4 lists.
msousa@353: # These macros are necessary as long as will still need to support
msousa@353: # Autoconf-2.59 which quotes differently.
msousa@353: m4_define([lt_car], [[$1]])
msousa@353: m4_define([lt_cdr],
msousa@353: [m4_if([$#], 0, [m4_fatal([$0: cannot be called without arguments])],
msousa@353:        [$#], 1, [],
msousa@353:        [m4_dquote(m4_shift($@))])])
msousa@353: m4_define([lt_unquote], $1)
msousa@353: 
msousa@353: 
msousa@353: # lt_append(MACRO-NAME, STRING, [SEPARATOR])
msousa@353: # ------------------------------------------
msousa@353: # Redefine MACRO-NAME to hold its former content plus `SEPARATOR'`STRING'.
msousa@353: # Note that neither SEPARATOR nor STRING are expanded; they are appended
msousa@353: # to MACRO-NAME as is (leaving the expansion for when MACRO-NAME is invoked).
msousa@353: # No SEPARATOR is output if MACRO-NAME was previously undefined (different
msousa@353: # than defined and empty).
msousa@353: #
msousa@353: # This macro is needed until we can rely on Autoconf 2.62, since earlier
msousa@353: # versions of m4sugar mistakenly expanded SEPARATOR but not STRING.
msousa@353: m4_define([lt_append],
msousa@353: [m4_define([$1],
msousa@353: 	   m4_ifdef([$1], [m4_defn([$1])[$3]])[$2])])
msousa@353: 
msousa@353: 
msousa@353: 
msousa@353: # lt_combine(SEP, PREFIX-LIST, INFIX, SUFFIX1, [SUFFIX2...])
msousa@353: # ----------------------------------------------------------
msousa@353: # Produce a SEP delimited list of all paired combinations of elements of
msousa@353: # PREFIX-LIST with SUFFIX1 through SUFFIXn.  Each element of the list
msousa@353: # has the form PREFIXmINFIXSUFFIXn.
msousa@353: # Needed until we can rely on m4_combine added in Autoconf 2.62.
msousa@353: m4_define([lt_combine],
msousa@353: [m4_if(m4_eval([$# > 3]), [1],
msousa@353:        [m4_pushdef([_Lt_sep], [m4_define([_Lt_sep], m4_defn([lt_car]))])]]dnl
msousa@353: [[m4_foreach([_Lt_prefix], [$2],
msousa@353: 	     [m4_foreach([_Lt_suffix],
msousa@353: 		]m4_dquote(m4_dquote(m4_shift(m4_shift(m4_shift($@)))))[,
msousa@353: 	[_Lt_sep([$1])[]m4_defn([_Lt_prefix])[$3]m4_defn([_Lt_suffix])])])])])
msousa@353: 
msousa@353: 
msousa@353: # lt_if_append_uniq(MACRO-NAME, VARNAME, [SEPARATOR], [UNIQ], [NOT-UNIQ])
msousa@353: # -----------------------------------------------------------------------
msousa@353: # Iff MACRO-NAME does not yet contain VARNAME, then append it (delimited
msousa@353: # by SEPARATOR if supplied) and expand UNIQ, else NOT-UNIQ.
msousa@353: m4_define([lt_if_append_uniq],
msousa@353: [m4_ifdef([$1],
msousa@353: 	  [m4_if(m4_index([$3]m4_defn([$1])[$3], [$3$2$3]), [-1],
msousa@353: 		 [lt_append([$1], [$2], [$3])$4],
msousa@353: 		 [$5])],
msousa@353: 	  [lt_append([$1], [$2], [$3])$4])])
msousa@353: 
msousa@353: 
msousa@353: # lt_dict_add(DICT, KEY, VALUE)
msousa@353: # -----------------------------
msousa@353: m4_define([lt_dict_add],
msousa@353: [m4_define([$1($2)], [$3])])
msousa@353: 
msousa@353: 
msousa@353: # lt_dict_add_subkey(DICT, KEY, SUBKEY, VALUE)
msousa@353: # --------------------------------------------
msousa@353: m4_define([lt_dict_add_subkey],
msousa@353: [m4_define([$1($2:$3)], [$4])])
msousa@353: 
msousa@353: 
msousa@353: # lt_dict_fetch(DICT, KEY, [SUBKEY])
msousa@353: # ----------------------------------
msousa@353: m4_define([lt_dict_fetch],
msousa@353: [m4_ifval([$3],
msousa@353: 	m4_ifdef([$1($2:$3)], [m4_defn([$1($2:$3)])]),
msousa@353:     m4_ifdef([$1($2)], [m4_defn([$1($2)])]))])
msousa@353: 
msousa@353: 
msousa@353: # lt_if_dict_fetch(DICT, KEY, [SUBKEY], VALUE, IF-TRUE, [IF-FALSE])
msousa@353: # -----------------------------------------------------------------
msousa@353: m4_define([lt_if_dict_fetch],
msousa@353: [m4_if(lt_dict_fetch([$1], [$2], [$3]), [$4],
msousa@353: 	[$5],
msousa@353:     [$6])])
msousa@353: 
msousa@353: 
msousa@353: # lt_dict_filter(DICT, [SUBKEY], VALUE, [SEPARATOR], KEY, [...])
msousa@353: # --------------------------------------------------------------
msousa@353: m4_define([lt_dict_filter],
msousa@353: [m4_if([$5], [], [],
msousa@353:   [lt_join(m4_quote(m4_default([$4], [[, ]])),
msousa@353:            lt_unquote(m4_split(m4_normalize(m4_foreach(_Lt_key, lt_car([m4_shiftn(4, $@)]),
msousa@353: 		      [lt_if_dict_fetch([$1], _Lt_key, [$2], [$3], [_Lt_key ])])))))])[]dnl
msousa@353: ])