1

# libtool.m4 - Configure libtool for the host system. -*-Autoconf-*-

     2

#

     3

#   Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2003, 2004, 2005,

     4

#                 2006, 2007, 2008 Free Software Foundation, Inc.

     5

#   Written by Gordon Matzigkeit, 1996

     6

#

     7

# This file is free software; the Free Software Foundation gives

     8

# unlimited permission to copy and/or distribute it, with or without

     9

# modifications, as long as this notice is preserved.

    10

    11

m4_define([_LT_COPYING], [dnl

    12

#   Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2003, 2004, 2005,

    13

#                 2006, 2007, 2008 Free Software Foundation, Inc.

    14

#   Written by Gordon Matzigkeit, 1996

    15

#

    16

#   This file is part of GNU Libtool.

    17

#

    18

# GNU Libtool is free software; you can redistribute it and/or

    19

# modify it under the terms of the GNU General Public License as

    20

# published by the Free Software Foundation; either version 2 of

    21

# the License, or (at your option) any later version.

    22

#

    23

# As a special exception to the GNU General Public License,

    24

# if you distribute this file as part of a program or library that

    25

# is built using GNU Libtool, you may include this file under the

    26

# same distribution terms that you use for the rest of that program.

    27

#

    28

# GNU Libtool is distributed in the hope that it will be useful,

    29

# but WITHOUT ANY WARRANTY; without even the implied warranty of

    30

# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

    31

# GNU General Public License for more details.

    32

#

    33

# You should have received a copy of the GNU General Public License

    34

# along with GNU Libtool; see the file COPYING.  If not, a copy

    35

# can be downloaded from http://www.gnu.org/licenses/gpl.html, or

    36

# obtained by writing to the Free Software Foundation, Inc.,

    37

# 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.

    38

])

    39

    40

# serial 56 LT_INIT

    41

    42

    43

# LT_PREREQ(VERSION)

    44

# ------------------

    45

# Complain and exit if this libtool version is less that VERSION.

    46

m4_defun([LT_PREREQ],

    47

[m4_if(m4_version_compare(m4_defn([LT_PACKAGE_VERSION]), [$1]), -1,

    48

       [m4_default([$3],

    49

		   [m4_fatal([Libtool version $1 or higher is required],

    50

		             63)])],

    51

       [$2])])

    52

    53

    54

# _LT_CHECK_BUILDDIR

    55

# ------------------

    56

# Complain if the absolute build directory name contains unusual characters

    57

m4_defun([_LT_CHECK_BUILDDIR],

    58

[case `pwd` in

    59

  *\ * | *\	*)

    60

    AC_MSG_WARN([Libtool does not cope well with whitespace in `pwd`]) ;;

    61

esac

    62

])

    63

    64

    65

# LT_INIT([OPTIONS])

    66

# ------------------

    67

AC_DEFUN([LT_INIT],

    68

[AC_PREREQ([2.58])dnl We use AC_INCLUDES_DEFAULT

    69

AC_BEFORE([$0], [LT_LANG])dnl

    70

AC_BEFORE([$0], [LT_OUTPUT])dnl

    71

AC_BEFORE([$0], [LTDL_INIT])dnl

    72

m4_require([_LT_CHECK_BUILDDIR])dnl

    73

    74

dnl Autoconf doesn't catch unexpanded LT_ macros by default:

    75

m4_pattern_forbid([^_?LT_[A-Z_]+$])dnl

    76

m4_pattern_allow([^(_LT_EOF|LT_DLGLOBAL|LT_DLLAZY_OR_NOW|LT_MULTI_MODULE)$])dnl

    77

dnl aclocal doesn't pull ltoptions.m4, ltsugar.m4, or ltversion.m4

    78

dnl unless we require an AC_DEFUNed macro:

    79

AC_REQUIRE([LTOPTIONS_VERSION])dnl

    80

AC_REQUIRE([LTSUGAR_VERSION])dnl

    81

AC_REQUIRE([LTVERSION_VERSION])dnl

    82

AC_REQUIRE([LTOBSOLETE_VERSION])dnl

    83

m4_require([_LT_PROG_LTMAIN])dnl

    84

    85

dnl Parse OPTIONS

    86

_LT_SET_OPTIONS([$0], [$1])

    87

    88

# This can be used to rebuild libtool when needed

    89

LIBTOOL_DEPS="$ltmain"

    90

    91

# Always use our own libtool.

    92

LIBTOOL='$(SHELL) $(top_builddir)/libtool'

    93

AC_SUBST(LIBTOOL)dnl

    94

    95

_LT_SETUP

    96

    97

# Only expand once:

    98

m4_define([LT_INIT])

    99

])# LT_INIT

   100

   101

# Old names:

   102

AU_ALIAS([AC_PROG_LIBTOOL], [LT_INIT])

   103

AU_ALIAS([AM_PROG_LIBTOOL], [LT_INIT])

   104

dnl aclocal-1.4 backwards compatibility:

   105

dnl AC_DEFUN([AC_PROG_LIBTOOL], [])

   106

dnl AC_DEFUN([AM_PROG_LIBTOOL], [])

   107

   108

   109

# _LT_CC_BASENAME(CC)

   110

# -------------------

   111

# Calculate cc_basename.  Skip known compiler wrappers and cross-prefix.

   112

m4_defun([_LT_CC_BASENAME],

   113

[for cc_temp in $1""; do

   114

  case $cc_temp in

   115

    compile | *[[\\/]]compile | ccache | *[[\\/]]ccache ) ;;

   116

    distcc | *[[\\/]]distcc | purify | *[[\\/]]purify ) ;;

   117

    \-*) ;;

   118

    *) break;;

   119

  esac

   120

done

   121

cc_basename=`$ECHO "X$cc_temp" | $Xsed -e 's%.*/%%' -e "s%^$host_alias-%%"`

   122

])

   123

   124

   125

# _LT_FILEUTILS_DEFAULTS

   126

# ----------------------

   127

# It is okay to use these file commands and assume they have been set

   128

# sensibly after `m4_require([_LT_FILEUTILS_DEFAULTS])'.

   129

m4_defun([_LT_FILEUTILS_DEFAULTS],

   130

[: ${CP="cp -f"}

   131

: ${MV="mv -f"}

   132

: ${RM="rm -f"}

   133

])# _LT_FILEUTILS_DEFAULTS

   134

   135

   136

# _LT_SETUP

   137

# ---------

   138

m4_defun([_LT_SETUP],

   139

[AC_REQUIRE([AC_CANONICAL_HOST])dnl

   140

AC_REQUIRE([AC_CANONICAL_BUILD])dnl

   141

_LT_DECL([], [host_alias], [0], [The host system])dnl

   142

_LT_DECL([], [host], [0])dnl

   143

_LT_DECL([], [host_os], [0])dnl

   144

dnl

   145

_LT_DECL([], [build_alias], [0], [The build system])dnl

   146

_LT_DECL([], [build], [0])dnl

   147

_LT_DECL([], [build_os], [0])dnl

   148

dnl

   149

AC_REQUIRE([AC_PROG_CC])dnl

   150

AC_REQUIRE([LT_PATH_LD])dnl

   151

AC_REQUIRE([LT_PATH_NM])dnl

   152

dnl

   153

AC_REQUIRE([AC_PROG_LN_S])dnl

   154

test -z "$LN_S" && LN_S="ln -s"

   155

_LT_DECL([], [LN_S], [1], [Whether we need soft or hard links])dnl

   156

dnl

   157

AC_REQUIRE([LT_CMD_MAX_LEN])dnl

   158

_LT_DECL([objext], [ac_objext], [0], [Object file suffix (normally "o")])dnl

   159

_LT_DECL([], [exeext], [0], [Executable file suffix (normally "")])dnl

   160

dnl

   161

m4_require([_LT_FILEUTILS_DEFAULTS])dnl

   162

m4_require([_LT_CHECK_SHELL_FEATURES])dnl

   163

m4_require([_LT_CMD_RELOAD])dnl

   164

m4_require([_LT_CHECK_MAGIC_METHOD])dnl

   165

m4_require([_LT_CMD_OLD_ARCHIVE])dnl

   166

m4_require([_LT_CMD_GLOBAL_SYMBOLS])dnl

   167

   168

_LT_CONFIG_LIBTOOL_INIT([

   169

# See if we are running on zsh, and set the options which allow our

   170

# commands through without removal of \ escapes INIT.

   171

if test -n "\${ZSH_VERSION+set}" ; then

   172

   setopt NO_GLOB_SUBST

   173

fi

   174

])

   175

if test -n "${ZSH_VERSION+set}" ; then

   176

   setopt NO_GLOB_SUBST

   177

fi

   178

   179

_LT_CHECK_OBJDIR

   180

   181

m4_require([_LT_TAG_COMPILER])dnl

   182

_LT_PROG_ECHO_BACKSLASH

   183

   184

case $host_os in

   185

aix3*)

   186

  # AIX sometimes has problems with the GCC collect2 program.  For some

   187

  # reason, if we set the COLLECT_NAMES environment variable, the problems

   188

  # vanish in a puff of smoke.

   189

  if test "X${COLLECT_NAMES+set}" != Xset; then

   190

    COLLECT_NAMES=

   191

    export COLLECT_NAMES

   192

  fi

   193

  ;;

   194

esac

   195

   196

# Sed substitution that helps us do robust quoting.  It backslashifies

   197

# metacharacters that are still active within double-quoted strings.

   198

sed_quote_subst='s/\([["`$\\]]\)/\\\1/g'

   199

   200

# Same as above, but do not quote variable references.

   201

double_quote_subst='s/\([["`\\]]\)/\\\1/g'

   202

   203

# Sed substitution to delay expansion of an escaped shell variable in a

   204

# double_quote_subst'ed string.

   205

delay_variable_subst='s/\\\\\\\\\\\$/\\\\\\$/g'

   206

   207

# Sed substitution to delay expansion of an escaped single quote.

   208

delay_single_quote_subst='s/'\''/'\'\\\\\\\'\''/g'

   209

   210

# Sed substitution to avoid accidental globbing in evaled expressions

   211

no_glob_subst='s/\*/\\\*/g'

   212

   213

# Global variables:

   214

ofile=libtool

   215

can_build_shared=yes

   216

   217

# All known linkers require a `.a' archive for static linking (except MSVC,

   218

# which needs '.lib').

   219

libext=a

   220

   221

with_gnu_ld="$lt_cv_prog_gnu_ld"

   222

   223

old_CC="$CC"

   224

old_CFLAGS="$CFLAGS"

   225

   226

# Set sane defaults for various variables

   227

test -z "$CC" && CC=cc

   228

test -z "$LTCC" && LTCC=$CC

   229

test -z "$LTCFLAGS" && LTCFLAGS=$CFLAGS

   230

test -z "$LD" && LD=ld

   231

test -z "$ac_objext" && ac_objext=o

   232

   233

_LT_CC_BASENAME([$compiler])

   234

   235

# Only perform the check for file, if the check method requires it

   236

test -z "$MAGIC_CMD" && MAGIC_CMD=file

   237

case $deplibs_check_method in

   238

file_magic*)

   239

  if test "$file_magic_cmd" = '$MAGIC_CMD'; then

   240

    _LT_PATH_MAGIC

   241

  fi

   242

  ;;

   243

esac

   244

   245

# Use C for the default configuration in the libtool script

   246

LT_SUPPORTED_TAG([CC])

   247

_LT_LANG_C_CONFIG

   248

_LT_LANG_DEFAULT_CONFIG

   249

_LT_CONFIG_COMMANDS

   250

])# _LT_SETUP

   251

   252

   253

# _LT_PROG_LTMAIN

   254

# ---------------

   255

# Note that this code is called both from `configure', and `config.status'

   256

# now that we use AC_CONFIG_COMMANDS to generate libtool.  Notably,

   257

# `config.status' has no value for ac_aux_dir unless we are using Automake,

   258

# so we pass a copy along to make sure it has a sensible value anyway.

   259

m4_defun([_LT_PROG_LTMAIN],

   260

[m4_ifdef([AC_REQUIRE_AUX_FILE], [AC_REQUIRE_AUX_FILE([ltmain.sh])])dnl

   261

_LT_CONFIG_LIBTOOL_INIT([ac_aux_dir='$ac_aux_dir'])

   262

ltmain="$ac_aux_dir/ltmain.sh"

   263

])# _LT_PROG_LTMAIN

   264

   265

   266

## ------------------------------------- ##

   267

## Accumulate code for creating libtool. ##

   268

## ------------------------------------- ##

   269

   270

# So that we can recreate a full libtool script including additional

   271

# tags, we accumulate the chunks of code to send to AC_CONFIG_COMMANDS

   272

# in macros and then make a single call at the end using the `libtool'

   273

# label.

   274

   275

   276

# _LT_CONFIG_LIBTOOL_INIT([INIT-COMMANDS])

   277

# ----------------------------------------

   278

# Register INIT-COMMANDS to be passed to AC_CONFIG_COMMANDS later.

   279

m4_define([_LT_CONFIG_LIBTOOL_INIT],

   280

[m4_ifval([$1],

   281

          [m4_append([_LT_OUTPUT_LIBTOOL_INIT],

   282

                     [$1

   283

])])])

   284

   285

# Initialize.

   286

m4_define([_LT_OUTPUT_LIBTOOL_INIT])

   287

   288

   289

# _LT_CONFIG_LIBTOOL([COMMANDS])

   290

# ------------------------------

   291

# Register COMMANDS to be passed to AC_CONFIG_COMMANDS later.

   292

m4_define([_LT_CONFIG_LIBTOOL],

   293

[m4_ifval([$1],

   294

          [m4_append([_LT_OUTPUT_LIBTOOL_COMMANDS],

   295

                     [$1

   296

])])])

   297

   298

# Initialize.

   299

m4_define([_LT_OUTPUT_LIBTOOL_COMMANDS])

   300

   301

   302

# _LT_CONFIG_SAVE_COMMANDS([COMMANDS], [INIT_COMMANDS])

   303

# -----------------------------------------------------

   304

m4_defun([_LT_CONFIG_SAVE_COMMANDS],

   305

[_LT_CONFIG_LIBTOOL([$1])

   306

_LT_CONFIG_LIBTOOL_INIT([$2])

   307

])

   308

   309

   310

# _LT_FORMAT_COMMENT([COMMENT])

   311

# -----------------------------

   312

# Add leading comment marks to the start of each line, and a trailing

   313

# full-stop to the whole comment if one is not present already.

   314

m4_define([_LT_FORMAT_COMMENT],

   315

[m4_ifval([$1], [

   316

m4_bpatsubst([m4_bpatsubst([$1], [^ *], [# ])],

   317

              [['`$\]], [\\\&])]m4_bmatch([$1], [[!?.]$], [], [.])

   318

)])

   319

   320

   321

   322

## ------------------------ ##

   323

## FIXME: Eliminate VARNAME ##

   324

## ------------------------ ##

   325

   326

   327

# _LT_DECL([CONFIGNAME], VARNAME, VALUE, [DESCRIPTION], [IS-TAGGED?])

   328

# -------------------------------------------------------------------

   329

# CONFIGNAME is the name given to the value in the libtool script.

   330

# VARNAME is the (base) name used in the configure script.

   331

# VALUE may be 0, 1 or 2 for a computed quote escaped value based on

   332

# VARNAME.  Any other value will be used directly.

   333

m4_define([_LT_DECL],

   334

[lt_if_append_uniq([lt_decl_varnames], [$2], [, ],

   335

    [lt_dict_add_subkey([lt_decl_dict], [$2], [libtool_name],

   336

	[m4_ifval([$1], [$1], [$2])])

   337

    lt_dict_add_subkey([lt_decl_dict], [$2], [value], [$3])

   338

    m4_ifval([$4],

   339

	[lt_dict_add_subkey([lt_decl_dict], [$2], [description], [$4])])

   340

    lt_dict_add_subkey([lt_decl_dict], [$2],

   341

	[tagged?], [m4_ifval([$5], [yes], [no])])])

   342

])

   343

   344

   345

# _LT_TAGDECL([CONFIGNAME], VARNAME, VALUE, [DESCRIPTION])

   346

# --------------------------------------------------------

   347

m4_define([_LT_TAGDECL], [_LT_DECL([$1], [$2], [$3], [$4], [yes])])

   348

   349

   350

# lt_decl_tag_varnames([SEPARATOR], [VARNAME1...])

   351

# ------------------------------------------------

   352

m4_define([lt_decl_tag_varnames],

   353

[_lt_decl_filter([tagged?], [yes], $@)])

   354

   355

   356

# _lt_decl_filter(SUBKEY, VALUE, [SEPARATOR], [VARNAME1..])

   357

# ---------------------------------------------------------

   358

m4_define([_lt_decl_filter],

   359

[m4_case([$#],

   360

  [0], [m4_fatal([$0: too few arguments: $#])],

   361

  [1], [m4_fatal([$0: too few arguments: $#: $1])],

   362

  [2], [lt_dict_filter([lt_decl_dict], [$1], [$2], [], lt_decl_varnames)],

   363

  [3], [lt_dict_filter([lt_decl_dict], [$1], [$2], [$3], lt_decl_varnames)],

   364

  [lt_dict_filter([lt_decl_dict], $@)])[]dnl

   365

])

   366

   367

   368

# lt_decl_quote_varnames([SEPARATOR], [VARNAME1...])

   369

# --------------------------------------------------

   370

m4_define([lt_decl_quote_varnames],

   371

[_lt_decl_filter([value], [1], $@)])

   372

   373

   374

# lt_decl_dquote_varnames([SEPARATOR], [VARNAME1...])

   375

# ---------------------------------------------------

   376

m4_define([lt_decl_dquote_varnames],

   377

[_lt_decl_filter([value], [2], $@)])

   378

   379

   380

# lt_decl_varnames_tagged([SEPARATOR], [VARNAME1...])

   381

# ---------------------------------------------------

   382

m4_define([lt_decl_varnames_tagged],

   383

[m4_assert([$# <= 2])dnl

   384

_$0(m4_quote(m4_default([$1], [[, ]])),

   385

    m4_ifval([$2], [[$2]], [m4_dquote(lt_decl_tag_varnames)]),

   386

    m4_split(m4_normalize(m4_quote(_LT_TAGS)), [ ]))])

   387

m4_define([_lt_decl_varnames_tagged],

   388

[m4_ifval([$3], [lt_combine([$1], [$2], [_], $3)])])

   389

   390

   391

# lt_decl_all_varnames([SEPARATOR], [VARNAME1...])

   392

# ------------------------------------------------

   393

m4_define([lt_decl_all_varnames],

   394

[_$0(m4_quote(m4_default([$1], [[, ]])),

   395

     m4_if([$2], [],

   396

	   m4_quote(lt_decl_varnames),

   397

	m4_quote(m4_shift($@))))[]dnl

   398

])

   399

m4_define([_lt_decl_all_varnames],

   400

[lt_join($@, lt_decl_varnames_tagged([$1],

   401

			lt_decl_tag_varnames([[, ]], m4_shift($@))))dnl

   402

])

   403

   404

   405

# _LT_CONFIG_STATUS_DECLARE([VARNAME])

   406

# ------------------------------------

   407

# Quote a variable value, and forward it to `config.status' so that its

   408

# declaration there will have the same value as in `configure'.  VARNAME

   409

# must have a single quote delimited value for this to work.

   410

m4_define([_LT_CONFIG_STATUS_DECLARE],

   411

[$1='`$ECHO "X$][$1" | $Xsed -e "$delay_single_quote_subst"`'])

   412

   413

   414

# _LT_CONFIG_STATUS_DECLARATIONS

   415

# ------------------------------

   416

# We delimit libtool config variables with single quotes, so when

   417

# we write them to config.status, we have to be sure to quote all

   418

# embedded single quotes properly.  In configure, this macro expands

   419

# each variable declared with _LT_DECL (and _LT_TAGDECL) into:

   420

#

   421

#    <var>='`$ECHO "X$<var>" | $Xsed -e "$delay_single_quote_subst"`'

   422

m4_defun([_LT_CONFIG_STATUS_DECLARATIONS],

   423

[m4_foreach([_lt_var], m4_quote(lt_decl_all_varnames),

   424

    [m4_n([_LT_CONFIG_STATUS_DECLARE(_lt_var)])])])

   425

   426

   427

# _LT_LIBTOOL_TAGS

   428

# ----------------

   429

# Output comment and list of tags supported by the script

   430

m4_defun([_LT_LIBTOOL_TAGS],

   431

[_LT_FORMAT_COMMENT([The names of the tagged configurations supported by this script])dnl

   432

available_tags="_LT_TAGS"dnl

   433

])

   434

   435

   436

# _LT_LIBTOOL_DECLARE(VARNAME, [TAG])

   437

# -----------------------------------

   438

# Extract the dictionary values for VARNAME (optionally with TAG) and

   439

# expand to a commented shell variable setting:

   440

#

   441

#    # Some comment about what VAR is for.

   442

#    visible_name=$lt_internal_name

   443

m4_define([_LT_LIBTOOL_DECLARE],

   444

[_LT_FORMAT_COMMENT(m4_quote(lt_dict_fetch([lt_decl_dict], [$1],

   445

					   [description])))[]dnl

   446

m4_pushdef([_libtool_name],

   447

    m4_quote(lt_dict_fetch([lt_decl_dict], [$1], [libtool_name])))[]dnl

   448

m4_case(m4_quote(lt_dict_fetch([lt_decl_dict], [$1], [value])),

   449

    [0], [_libtool_name=[$]$1],

   450

    [1], [_libtool_name=$lt_[]$1],

   451

    [2], [_libtool_name=$lt_[]$1],

   452

    [_libtool_name=lt_dict_fetch([lt_decl_dict], [$1], [value])])[]dnl

   453

m4_ifval([$2], [_$2])[]m4_popdef([_libtool_name])[]dnl

   454

])

   455

   456

   457

# _LT_LIBTOOL_CONFIG_VARS

   458

# -----------------------

   459

# Produce commented declarations of non-tagged libtool config variables

   460

# suitable for insertion in the LIBTOOL CONFIG section of the `libtool'

   461

# script.  Tagged libtool config variables (even for the LIBTOOL CONFIG

   462

# section) are produced by _LT_LIBTOOL_TAG_VARS.

   463

m4_defun([_LT_LIBTOOL_CONFIG_VARS],

   464

[m4_foreach([_lt_var],

   465

    m4_quote(_lt_decl_filter([tagged?], [no], [], lt_decl_varnames)),

   466

    [m4_n([_LT_LIBTOOL_DECLARE(_lt_var)])])])

   467

   468

   469

# _LT_LIBTOOL_TAG_VARS(TAG)

   470

# -------------------------

   471

m4_define([_LT_LIBTOOL_TAG_VARS],

   472

[m4_foreach([_lt_var], m4_quote(lt_decl_tag_varnames),

   473

    [m4_n([_LT_LIBTOOL_DECLARE(_lt_var, [$1])])])])

   474

   475

   476

# _LT_TAGVAR(VARNAME, [TAGNAME])

   477

# ------------------------------

   478

m4_define([_LT_TAGVAR], [m4_ifval([$2], [$1_$2], [$1])])

   479

   480

   481

# _LT_CONFIG_COMMANDS

   482

# -------------------

   483

# Send accumulated output to $CONFIG_STATUS.  Thanks to the lists of

   484

# variables for single and double quote escaping we saved from calls

   485

# to _LT_DECL, we can put quote escaped variables declarations

   486

# into `config.status', and then the shell code to quote escape them in

   487

# for loops in `config.status'.  Finally, any additional code accumulated

   488

# from calls to _LT_CONFIG_LIBTOOL_INIT is expanded.

   489

m4_defun([_LT_CONFIG_COMMANDS],

   490

[AC_PROVIDE_IFELSE([LT_OUTPUT],

   491

	dnl If the libtool generation code has been placed in $CONFIG_LT,

   492

	dnl instead of duplicating it all over again into config.status,

   493

	dnl then we will have config.status run $CONFIG_LT later, so it

   494

	dnl needs to know what name is stored there:

   495

        [AC_CONFIG_COMMANDS([libtool],

   496

            [$SHELL $CONFIG_LT || AS_EXIT(1)], [CONFIG_LT='$CONFIG_LT'])],

   497

    dnl If the libtool generation code is destined for config.status,

   498

    dnl expand the accumulated commands and init code now:

   499

    [AC_CONFIG_COMMANDS([libtool],

   500

        [_LT_OUTPUT_LIBTOOL_COMMANDS], [_LT_OUTPUT_LIBTOOL_COMMANDS_INIT])])

   501

])#_LT_CONFIG_COMMANDS

   502

   503

   504

# Initialize.

   505

m4_define([_LT_OUTPUT_LIBTOOL_COMMANDS_INIT],

   506

[

   507

   508

# The HP-UX ksh and POSIX shell print the target directory to stdout

   509

# if CDPATH is set.

   510

(unset CDPATH) >/dev/null 2>&1 && unset CDPATH

   511

   512

sed_quote_subst='$sed_quote_subst'

   513

double_quote_subst='$double_quote_subst'

   514

delay_variable_subst='$delay_variable_subst'

   515

_LT_CONFIG_STATUS_DECLARATIONS

   516

LTCC='$LTCC'

   517

LTCFLAGS='$LTCFLAGS'

   518

compiler='$compiler_DEFAULT'

   519

   520

# Quote evaled strings.

   521

for var in lt_decl_all_varnames([[ \

   522

]], lt_decl_quote_varnames); do

   523

    case \`eval \\\\\$ECHO "X\\\\\$\$var"\` in

   524

    *[[\\\\\\\`\\"\\\$]]*)

   525

      eval "lt_\$var=\\\\\\"\\\`\\\$ECHO \\"X\\\$\$var\\" | \\\$Xsed -e \\"\\\$sed_quote_subst\\"\\\`\\\\\\""

   526

      ;;

   527

    *)

   528

      eval "lt_\$var=\\\\\\"\\\$\$var\\\\\\""

   529

      ;;

   530

    esac